Readme file
SERIES C
 Applied Statistics
Variance estimation in complex survey sampling for generalized linear models, by S. Natarajan, S. R. Lipsitz, G. Fitzmaurice, C. G. Moore and R. Gonin, pages 75–87;
The data are in the file h70_female.sas7bdat:
LIBNAME PUFLIB 'C:\PUFLIB';
data meps;
set puflib.h70_female;
run;
* Table 2. SAS program to obtain estimates in Table 1*
/* GLIM ESTIMATE UNDER SRS */
proc glimmix data=meps ;
_variance_ = _mu_**1.5 ;
model totexp02 = age smoke race pov insur phealth meds /link=log s ;
random _residual_; /* adds scale parameter to variance */
weight wt02 ;
output out=meps2 pred=_xb_ ;
run;
data meps2;
set meps2;
mu = exp(_xb_);
y_ = ( _xb_* mu + totexp02 - mu )/sqrt(mu**1.5);
intercep = mu/sqrt(mu**1.5) ;
age = age*intercep ;
smoke =smoke*intercep ;
race =race*intercep ;
pov = pov*intercep ;
insur = insur*intercep ;
phealth = phealth*intercep ;
meds = meds * intercep ;
run;
/* GEE ESTIMATE UNDER cluster sampling (no stratification) */
proc SURVEYREG data=meps2;
cluster varstr varpsu;
model y_ = intercep age smoke race pov insur phealth meds /noint;
weight wt02 ;
run;
/* ESTIMATE UNDER stratified cluster sampling */
proc SURVEYREG data=meps2;
stratum varstr;
cluster varpsu;
model y_ = intercep age smoke race pov insur phealth meds /noint;
weight wt02 ;
run;
Sundar Natarajan
New York University School of Medicine
Room 11101-S
423 East 23rd Street
New York
NY 10010-5013
USA
E-mail: natars01@med.nyu.edu
|
